WinCC数据报表实现方法介绍

本文对数据报表的需求进行了分析,结合WinCC就复杂数据报表的实现进行了介绍。

 

在工业生产中报表一直占有非常重要的部分,它一般用来记录现场的工艺参数和统计信息。早期是由人工抄录然后统计出相关的报表。进入计算机控制阶段,这份工作就需要工控软件来实现。对于工控行业的工程师来说:如何开发适合用户需求的报表一直是个难题。论坛上很多人都在寻求灵活高效的解决方法。

经过这段时间的网上讨论。综合网友们的意见和建议,我们做了总结。并结合WinCC软件本身作了相关的说明。希望能对大家在以后的报表开发中有所帮助。

接下来就从报表的需求分析、WinCC报表系统的应用、复杂报表的WinCC报表系统实现这几个部分来分别介绍。最后总结出WinCC报表系统在应用的优缺点和常见的问题的解决方法。

1.报表的需求分析

从需求上来讲报表一般分为:内容上的需求、样式上和任务上的需求。

1.1内容需求

       内容上一般涉及到数据的求和、平均、最大值、最小值等计算,同时也会涉及到关系的处理,比如班组相关对应信息的统计分析等。下面是一个很典型的报表需求,就很能说明这样的问题:

1. 月报表分析

    此报表是典型的工业现场应用,在数据采集没有难度。唯一的难度在于四班三倒后,每个月班的出勤日是不一样的,这样对于月报来说,计算出本月每个班的出勤日是需要些算法。此类报表在连续生产的行业需求很广泛。比如:钢铁冶金行业需要一天24小时不停运转的系统。

还有一种内容上是分总的关系,就是一部分是简单的数据记录,另一部分是对上一部分数据的统计,比如汇总、求和、平均等。如下图也是很典型的应用:

2. 总分报表

另外一种就是涉及到混合排列的问题,一张表上既有分项数据,中间也涉及到统计信息,同时也会添加一些实时的信息在上面。如下图:

3. 复杂报表

这是一个复杂的报表,中间涉及到分项的记录,数据求平均,和一些操作信息的记录。既有历史数据也有实时信息。

当然更复杂的报表需求也是有的,比如说涉及到一张报表上既有实时信息又有历史信息同时还涉及趋势视图、报警信息等。用户自己可以灵活的定义报表的内容和样式。比如下图:

4.用户定制报表样式

内容上的需求就本质来讲是对客户关心信息的总结和整理。内容的需求也就决定了报表的样式和可能采用的数据处理方式。

1.2报表样式和打印任务

    从上面的分析我们不难看出,报表在样式上要么是固定的,就是事先设计好报表的样式,然后把一个一个数据填写上去。这也是传统报表延续下来的一种方式:格式固定、内容固定(比如:图1和图3)。

  另一种就是格式样式固定,但是数据信息不固定。可能返回很多的数据集,也可能是没有数据。这对报表系统的数据归纳能力提出了要求。但是对样式上没有特别明确的需求。

最后一种就是比较复杂的问题,报表内容不固定、样式不固定完全由用户自己设计和决定显示的内容。

其实报表的打印任务很简单就是事件触发打印或者定时打印。

更深层次的分析。报表其实就是数据的展示问题,早期没有存储设备,只能人共抄写下来。现在有了机器存储。其实我们最终需要的就是一个数据的统计分析和显示。            

当然如果能把这些报表的样式和需求以电子版的样式在网络上共享。我想很多人可以接受不用打印输出的报表。最终关心的是这些数据如实的存储下来,并可以随时查阅。

  对于以上的问题,各家软件都有相应的解决方法。那么WinCC中提供了哪些方法来应对这些需求呢?

2WinCC的报表系统

    作为一款监控组态软件,WinCC针对需求提供了强大的报表组态功能。来帮助大家应对客户这方面的需求。从以下几个方面进行分析:数据存储、数据分析和数据输出。这也是处理报表问题的经典思路。

2.1数据存储

  就存储而言,如果能自由灵活的记录数据的统计分析结果那是再好不过的了。其实WinCC的过程归档功能提供了强大的数据处理能力。我们可以在归档管理中灵活的控制归档的动作和内容。如下图:

图5.过程值变量归档定义

仔细分析这个界面,我们几乎可以定义所有需要的数据统计种类。

1、周期的记录

2、非周期的动作触发

3、动作触发的周期记录

在数据处理上WinCC可以自动的统计出平均值、最大值、最小值等数据信息。

6.归档设置界面

  对于过程归档数据的访问,我们可以使用WinCC的在线表格控件、WinCC报表编辑器中自带的打印控件,同时也可以使用Connectivity Pack选件使用脚本读出数据。只有安装了该选件才支持特定的语法访问归档数据(该选件需要单独的授权)。对于有一定编程功底的工程师来说Connectivity Pack选件是一个很好地分析和数据处理工具。在后面会有相应的应用实例介绍。

    很多人熟悉数据库的操作,那么能不能像操作数据库那样操作WinCC存储的数据呢?WinCC为我们提供了另一个强大的数据存储和处理工具:用户归档。

用户归档编辑器是一个WinCC的附加选件,需要安装相应的授权才能使用,否则只能使用DEMO模式。它可以用来在服务器 PC 上连续的保存来自技术过程的数据。 在图形编辑器中,可以组态 WinCC 用户归档表格元素来以表格显示运行系统中用户归档的在线数据。用户归档还可用于准备自动化系统(例如 S5S7)的数据。如果必要,数据可以配方或设定值的形式从控制器读出。
 

7.用户归档界面

    用户归档的控制变量可以很好地实现数据的读取和写入。从而免去了用户自己写脚本的工作。在用户归档编辑器中,可以最多组态 500 个归档和 500 个视图。 每个归档最多可创建 500 个域。归档中的数据记录的最大数目受到限制,取决于已组态列的数目和归档中包含的数据记录。 列和数据记录的乘积不能大于 320000。这样用户归档基本上可以满足数据存储量不是很大的需求。同时又可以像操作数据库那样操作数据。很方便实用。

当然更灵活的方法就是使用WinCC的脚本操作外部数据库。这个已经超出了咱们讨论的范围。

2.2数据分析和输出

      其实这两个问题我们需要结合来讲。如何把存储和分析的结果很好地展示出来,这应该是大家最关心也是对报表系统体会最深的地方。很多时候我们的问题就出现在如何分析和展示数据上。很多人希望报表格式能像EXCEL那样灵活。当然我们可以把数据读出来写入EXCEL这不失为一个方法。但是这需要开发者的一些编程功底。如何不用编程序或者使用很少的程序代码就能实现报表功能呢?其实WinCC在数据分析和数据输出上提供了很好的工具。

最简单和直接的方法,就是调用WinCC的控件集成的打印功能。它是一种所见即所得的方式实现的打印工具。用户可以很轻松的执行打印任务。
    
对于普通归档的访问如果编程的话WinCC提供了Connectivity pack工具,用于分析和统计数据。对于用户归档WinCC的报表系统提供了直接的接口控件。同时也可以像操作普通数据库的表一样来操作用户归档中的归档和视图。对于外部数据WinCC也提供了ODBC数据表和数据域控件来直接连接获取数据。从而省去了部分编写数据库访问脚本的工作。如下图:

8.报表系统选件

9.ODBC动态对象

对于这些控件只需要简单的配置就能得到相应的数据结果。

10. 参数配置图

其中ODBC数据源变量用于填写数据源的名称,SQL语句变量用于创建一个变量写入查询条件。列数处填写返回数据记录的变量数。

很多人理想中的报表:是既有EXCEL的易用性同时又能兼顾很好的数据库接口。并在系统中保留EXCEL的数据统计分析功能和数据展示功能。

   其实WinCC是可以实现这样的报表的。WinCC有一个选件DataMonitor它的一项功能就是使用EXCEL连接WinCC的归档数据,主要就是结合WinCC的存储功能和EXCEL强大的数据处理功能来实现满足报表需求。同时它可以把相应的报表发布到网络上,实现网络的共享。用户还可以使用这个工具实现自定义报表样式。

该产品的定位,主要是对现场工艺和采集数据的分析、整理和发布。它包括"Process Screens""Webcenter""Trends and Alarms""Excel Workbooks"、等工具,可以根据不同的工具实现不同的功能。

11.WinCC/DataMonitor的操作界面

3.复杂报表的WinCC报表系统实现分析

     针对需求如何使用WinCC的报表系统实现复杂的报表呢?之前已经发了一个使用用户归档结合ODBC数据表控件实现复杂报表的文档。下面介绍使用Connectivity Pack结合普通归档如何实现复杂报表(以图1为例)。论坛上有位网友已经使用用户归档实现了该种报表,那么我们看看如实使用普通归档实现。

要求:现场是四班三运转,月底的时候对各个班的数据情况进行统计分析。

难点:各个班的上班时间不固定,每月的天数不固定。涉及到最大值、最小值和平均值的计算。

关键点:在于如何确立某班和某一时间段的对应关系。

3.1普通归档结合Connectivity Pack实现报表

首先数据存储问题。WinCC的归档中,对应一个过程变量其实可以生成多个归档变量(如图12)。归档的启动和停止可以由事件来控制(图13)。那么可以通过不同的用户登录来确定启动哪一个归档。从而确定班组和数据的对应关系。

12.归档定义

13.归档起始和停止动作的定义

创建全局动作如下(针对两个班组的测试代码,三个班的类似):

int gscAction( void )

{

#pragma option(mbcs)

if(!strcmp(GetTagChar("@CurrentUser"),"yiban"))

{

      SetTagBit("AarcE",0);   //Return-Type: BOOL

      SetTagBit("AarcB",1);   //Return-Type: BOOL

 

      SetTagBit("BarcE",1);   //Return-Type: BOOL

      SetTagBit("BarcB",0);   //Return-Type: BOOL

}

else if(!strcmp(GetTagChar("@CurrentUser"),"erban"))

{

      SetTagBit("BarcE",0);   //Return-Type: BOOL

      SetTagBit("BarcB",1);   //Return-Type: BOOL

 

      SetTagBit("AarcE",1);   //Return-Type: BOOL

      SetTagBit("AarcB",0);   //Return-Type: BOOL    

}

 

}

该动作通过WinCC内部变量@CurrentUser的变化来触发。

14.触发条件

这样在项目中A班的用户登录就触发ATagArc变量的归档,B班的用户登录就触发BTagArc。从而达到分班统计的目的。过程变量属性在这里我们选择实际值。

15.归档参数设置

其次数据分析。在归档设计中,已经确定了数据和班组的对应关系。那么下一步就是如何整理数据了。在这里我们需要借助于WinCC的一个选件Connectivity Pack来实现,通过该软件可以使用特定的语法格式访问WinCC的归档数据。在画面中添加一个按钮创建如下脚本(只有安装了Connectivity Pack选件才支持下面的归档访问方式):

Dim sPro, sDsn, sSer,sCon, sSql

Dim V,Sum,Avg,Std,Min,Max

Dim conn, oRs, oCom, oList, oItem

Dim m,n,s,nRec

Dim BeginTime

Set BeginTime = HMIRuntime.Tags("BeginTime")

Dim EndTime

Set EndTime = HMIRuntime.Tags("EndTime")

Dim Printer0

Set Printer0 = HMIRuntime.Tags("Printer")

 

'建立连接

sPro = "Provider=WinCCOLEDBProvider.1;"

sDsn="Catalog=CC_FXReport_09_02_08_13_58_39R;"

sSer = "Data Source=.\WinCC"

sCon = sPro + sDsn + sSer

 

BeginTime.Read

EndTime.Read

sSql="Tag:R,'MyPA\ATagArc','" + BeginTime.Value + "','"+ EndTime.Value +"'"

MsgBox "Opened with " & vbCr & sCon & vbCr & sSql & vbCr, vbOKCancel

      Set conn=CreateObject("ADODB.Connection")

            conn.ConnectionString = sCon

            conn.CursorLocation = 3  

            conn.Open

      Set oRs=CreateObject("ADODB.Recordset")

      Set oCom=CreateObject("ADODB.Command")

            oCom.CommandType = 1

      Set oCom.ActiveConnection = conn

            oCom.CommandText = sSql

      Set   oRs = oCom.Execute

            n=oRs.RecordCount'返回的数据集数

            MsgBox n

            If (n>0)Then

                  oRs.MoveFirst

                  n = 0

                  Sum = 0

                  Avg = 0

                  Min = oRs.Fields(2).Value    

                  Max = oRs.Fields(2).Value    

                  Do While Not oRs.EOF

                        n = n + 1

                        V = oRs.Fields(2).Value

                        Sum = Sum + V

                         If V>Max Then Max = V

                         If V<Min Then Min = v

                        oRs.MoveNext

                  Loop 

                  oRs.Close

                  If(n>1) Then Avg = Sum / n

                  HMIRuntime.Tags("incount").Write n

                  HMIRuntime.Tags("AavgTag").Write FormatNumber(Avg,2)

                  HMIRuntime.Tags("AmaxTag").Write FormatNumber(Max,2)

                  HMIRuntime.Tags("AMinTag").Write FormatNumber(Min,2)

            Else

                   HMIRuntime.Trace "selection return no fields"&vbNewLine

            End If

      conn.Close

Set oCom= Nothing

Set oRs=Nothing

Set conn=Nothing

'打印调用(创建了一个全局动作通过Printer的变化调用打印作业)

Printer0.Read

If Printer0.Value = 0 Then

      Printer0.Write 1

Else

      Printer0.Write  0

End If     

上面的方法就能得出A班的最大值、最小值和平均值,并把这些值存放在预先定义的内部变量里。同样的方法可以求出别班的数据信息。

最后就是布局设计。这个布局的设计原理很简单,就是把变量添加到布局中。排列对齐就可以了。如下图:

16.报表布局

最后组态输出界面。在画面中组态如下界面,调用脚本和打印任务就可以了。

17.操作界面

该程序可以实现对任意时间范围呢的数据进行统计打印。输出结果如下图:

18.打印输出

3.2用户归档实现分总式报表

报表图2涉及到数据的统计。单纯的存储不难,关键如何统计。从报表上分析,一天只会产生一条记录。完全可以选择使用用户归档实现。

首先在用户归档中创建一个归档,分别连接相应的需要记录的变量。并创建一个字符串类型的域用于存储日期。

19.用户归档

针对用户归档创建如下控制变量:

20.控制变量

关于控制变量的说明参考:

WinCC Information system-->选项--〉用户归档--〉组态--〉组态用户归档--〉控制变量的属性。当ID=-1 指令=6时,就可以把过程值存放到归档数据库中。

关于日期可以通过如下脚本得到:

riqi=CStr(Year(Now))&"-"&CStr(Month(Now))&"-"&CStr(Day(Now))

可以新建一个系统变量选择日期函数,通过每天的变化触发用户归档控制变量的指令和ID的变化,从而达到定时触发的目的。如图:

21.系统变量定义

这样我们就得到了每天的数据记录。下一步组态页面。在页面布局中添加一个用户归档表格控件、一个静态文本和一个ODBC数据库表。为了实现分页功能需要对静态文本的属性作如下设置:

22.页面布局

23.静态文本属性设置

下面我们分别设置用户归档和ODBC数据库表控件的参数。

23.归档控件设置

23.ODBC控件设置

画面中查寻按钮的代码:

Dim riqivar

Set riqivar = HMIRuntime.Tags("riqivar")

Dim xinjiangFilter

Set xinjiangFilter = HMIRuntime.Tags("xinjiangFilter")

Dim xinjiangorder

Set xinjiangorder = HMIRuntime.Tags("xinjiangorder")

Dim mytestsql

Set mytestsql = HMIRuntime.Tags("mytestsql")

riqivar.Read

xinjiangFilter.Read

xinjiangFilter.Write " MyDate like '"&riqivar.Value&"%'"

xinjiangorder.Read

xinjiangorder.Write "MyDate ASC"

mytestsql.Read

mytestsql.Write "select sum(picishu)as '批次数',sum(zongzl) as '总重量',sum(zhuliao) as '主料',sum(fuliao1) as '1#辅料',sum

(fuliao2) as '2#辅料',sum(fuliao3) as '3#辅料',sum(fuliao4) as '4#辅料',sum(fuliao5) as '5#辅料',sum(fuliao6) as '6#辅料'

from UA#peixianchengzhong where MyDate like '"&riqivar.Value&"%'"

至此在画面中输入查询日期的条件执行上面的代码就能返回相应的数据集。最后调用打印任务就可以了。

打印中常见问题的说明希望对大家有所帮助。

整点触发问题

可以通过在变量管理à SYSTEM INFO下创建变量用于取得系统小时值。这个值是随着系统时钟而变化的。一旦改变就可以用来触发归档或者打印任务。

也可以通过脚本实现,参照网上的例子:如何整点启动归档:http://support.automation.siemens.com/CN/view/zh/11012406

对齐问题WinCC提供很好的数据接口,那么在报表格式上来讲如何控制一直是个难题。下面是一些细节介绍希望对大家能有所帮助。

通过菜单栏中的放大功能可以很好的查看控件的对齐效果。

24. 放大功能

通过菜单栏 工具〉设置,可以把页面精确设置到毫米,同时可以设定控件是否和网格对齐。从而方便我们的排版设计。

25. 网格设置

4.WinCC报表功能总结

通过上面的分析我们不难看出,WinCC的报表系统提供了很好的数据接口,我们可以很方便的就取出WinCC的归档数据和外部数据库的数据。无需很多的编程知识。同时在过程归档可以很容易的就得到变量的最大值、最小值、平均值等信息。

过程值归档中无法建立关系和对字符串进行归档。这些功能使用用户归档可以实现。其实很多人不使用WinCC自带的报表功能,很大程度上是因为布局不好掌控。确切来讲在格式的控制上WinCC是有些不适合中国国情。

延伸话题:其实数据的报表打印就是对数据的存储记录工作,有时候我们需要的并不是打印出一张纸,而是需要对数据的分析和整理。从这个角度出发,WinCC如果能提供一个强大的前台数据统计分析控件就更完美了。当然对于数据的分析统计,在现场应用中很大程度上是由MIS系统和ERP系统来实现的。WinCC在这个环节是作为一个数据源的身份出现的。但是它的DataMonitor工具提供了很好的数据接口,用于分析和输出数据。也不失为一个很好的数据分析统计选件。

5.使用脚本和EXCEL实现实时数据报表

论坛中很多人使用VBSEXCEL实现报表功能。下面做了一个示例仅供参考:

5.1WINCC中使用VBS脚本通过EXCEL实现实时数据报表

使用VBS脚本和EXCEL工具,同样可以生成需要的报表。一般的思路是:预先使用excel设计好报表的样式,然后在WinCC中使用VBS脚本把相应的数据写入事先定义好的表格中。下面给出实现的方法。

右键点击按钮打开属性对话框,在事件页右键单击鼠标动作选择VBS动作。如下图:

26. 动作定义

在该事件中写入如下脚本:

定义变量

Dim objExcelApp,objExcelBook,objExcelSheet

Dim tagwendu,tagyali,tagliuliang,tagzhongliang,tagyuanliao,tagchengfen

Dim tagshijian,sheetname,username,zhushi

Dim qushi1,qushi2,qushi3,qushi4,qushi5,qushi6,qushix,tagstring,qushivalue

Dim x,y,z,i,j

Dim msg

'声明

Set tagwendu=HMIRuntime.Tags("wendu")

Set tagyali=HMIRuntime.Tags("yali")

Set tagliuliang=HMIRuntime.Tags("liuliang")

Set tagzhongliang=HMIRuntime.Tags("zhongliang")

Set tagyuanliao=HMIRuntime.Tags("yuanliao")

 

Set tagchengfen=HMIRuntime.Tags("chengfen")

Set username=HMIRuntime.Tags("@CurrentUserName")

Set zhushi=HMIRuntime.Tags("zhushi")

 

  msg="ok"   

  sheetname="sheetdemo"  

'判断是否打开模版,如果打开先关闭保存

 On Error Resume Next

 Dim ExcelApp,ExcelBook

 Set ExcelApp  = GetObject(,"Excel.Application")

 If TypeName(ExcleApp) = "Application" Then

  For Each ExcelBook In ExcelApp.WorkBooks

   If ExcelBook.FullName = "D:\excelreport\winccvbsexcel.xls" Then

       ExcelApp.ActiveWorkbook.Save

     ExcelApp.Workbooks.Close

     ExcelApp.Quit

       Set ExcelApp= Nothing

       Exit For

   End If

  Next

 End If

'创建对象

Set objExcelApp =CreateObject("Excel.Application")

  'open  file

  objExcelApp.Visible=True

  objExcelApp.Workbooks.Open"D:\excelreport\winccvbsexcel.xls"     

  objExcelApp.Worksheets(sheetname).Activate

'清除模版数据

With objExcelApp.Worksheets(sheetname)

  For i=5 To 25

     For j=1 To 7

      .cells(i,j)=Null

     Next

  Next

  For i=26 To 26

     For j=1 To 6

      .cells(i,j)=Null

     Next

  Next

End With     

'实时数据写入  

  tagshijian=Now

  objExcelApp.Worksheets(sheetname).cells(2,2).value= tagshijian

  username.Read

  objExcelApp.Worksheets(sheetname).cells(2,7).value= username.Value

  zhushi.Read

  objExcelApp.Worksheets(sheetname).cells(27,7).value= zhushi.Value

  objExcelApp.Worksheets(sheetname).cells(27,7).Font.Bold = TRUE

    objExcelApp.Worksheets(sheetname).cells(27,7).Interior.ColorIndex = 25

    objExcelApp.Worksheets(sheetname).cells(27,7).Font.ColorIndex = 7

    objExcelApp.Worksheets(sheetname).cells(27,7).Font.size=18

  tagstring="qushi"

  For i=1 To 6

        For j=30 To 35

              qushix=tagstring&CStr(i)

              Set qushivalue=HMIRuntime.Tags(qushix)

              qushivalue.Read

              objExcelApp.Worksheets(sheetname).cells(j,2).value= qushivalue.Value

        Next

   Next

For i=5 To 25

  With objExcelApp.Worksheets(sheetname)

        .cells(i,1).value= tagshijian

        tagwendu.Read

        .cells(i,2).value= tagwendu.Value

        tagyali.Read

        .cells(i,3).value= tagyali.Value

        tagliuliang.Read

        .cells(i,4).value= tagliuliang.Value 

        tagzhongliang.Read

        .cells(i,5).value= tagzhongliang.Value 

        tagyuanliao.Read

        .cells(i,6).value= tagyuanliao.Value 

        tagchengfen.Read

        .cells(i,7).value= tagchengfen.Value 

  End With

  Next       

MsgBox msg

'关闭保存

Dim patch,filename

filename=CStr(Year(Now))&CStr(Month(Now))&CStr(Day(Now))&CStr(Hour(Now))+CStr(Minute(Now))&CStr(Second(Now))

patch= "d:\"&filename&"demo.xls"

objExcelApp.ActiveWorkbook.SaveAs patch

objExcelApp.Workbooks.Close

objExcelApp.Quit

Set objExcelApp= Nothing

输出结果如下图:

27. 输出结果

5.2如何使用EXCEL访问WinCC中的实时数据实现报表

如果项目已经做好了,不想改动现有项目。那么可以使用EXCEL通过OPC方式访问WinCC项目的数据。预先定义好EXCEL表格样式,通过以下方式实现。

通过以下步骤打开EXCEL中的VB编辑器。

28.打开编辑器

引用WinCC提供的OPC客户端Control控件: Siemens OPC DAAutomation 2.0( SOPCDAAuto.dll)

29.打开引用界面

 

30.对象引用

 

创建起始画面

31.创建画面

编程实现

变量声明

Option Explicit

Option Base 1

Const ServerName = "OPCServer.WinCC"

Dim WithEvents MyOPCServer As OPCServer

Dim WithEvents MyOPCGroup As OPCGroup

Dim MyOPCGroupColl As OPCGroups

Dim MyOPCItemColl As OPCItems

Dim MyOPCItems As OPCItems

Dim MyOPCItem As OPCItem

Dim ClientHandles(10) As Long

Dim ServerHandles() As Long

Dim Values(1) As Variant

Dim Errors() As Long

Dim ItemIDs(10) As String

Dim GroupName As String

Dim NodeName As String

Dim fxItemValue(10) As Variant

在按钮启动OPC客户端中添加以下代码

'---------------------------------------------------------------------

' 目的: 连接到 OPC_server,创建组并添加条目

'---------------------------------------------------------------------

  ' 发生错误则转到 ErrorHandler

  '----------- 可以自由选择 ClientHandle GroupName

Dim i As Integer

‘On Error GoTo HANDLEeRROR

    For i = 1 To 7

        ClientHandles(i) = i          

 '  先配置名柄索引 这将在读取OPC标签值时可要用到

    Next i

 ' ClientHandles(1) = 1

  GroupName = "MyGroup"

  '----------- 从窗口对话框中取得 ItemID

  NodeName = txtNoteName.Value

  ItemIDs(1) = Range("j5").Value’EXCEL表格j5中读取变量名称

  ItemIDs(2) = Range("j6").Value

  ItemIDs(3) = Range("j7").Value

  ItemIDs(4) = Range("j8").Value

  ItemIDs(5) = Range("j9").Value

  ItemIDs(6) = Range("j10").Value

  '----------- 取得 OPC-Server 实例

  Set MyOPCServer = New OPCServer

  MyOPCServer.Connect ServerName, NodeName

  Set MyOPCGroupColl = MyOPCServer.OPCGroups

  '----------- 设置用于添加组的默认活动状态

  MyOPCGroupColl.DefaultGroupIsActive = True

  '----------- 将我们的组添加到集合中

  Set MyOPCGroup = MyOPCGroupColl.Add(GroupName)

  Set MyOPCItemColl = MyOPCGroup.OPCItems

  '----------- 调价一个条目,即返回 ServerHandle

  MyOPCItemColl.AddItems 10, ItemIDs, ClientHandles, ServerHandles, Errors

  '----------- 订阅的组收到异步通知

  MyOPCGroup.IsSubscribed = True

  Exit Sub

ErrorHandler:

  MsgBox "Error: " & Err.Description, vbCritical, "ERROR"

在按钮停止OPC客户端中添加以下代码

'---------------------------------------------------------------------

' 目的: 释放对象并断开与服务器的连接

'---------------------------------------------------------------------

  '----------- 释放组和服务器对象

  MyOPCGroupColl.RemoveAll

  '----------- 断开与服务器的连接并清除

  MyOPCServer.Disconnect

  Set MyOPCItemColl = Nothing

  Set MyOPCGroup = Nothing

  Set MyOPCGroupColl = Nothing

  Set MyOPCServer = Nothing

创建实时刷新数据的函数

' 目的: 组中的数值、质量或时间标志改变时,该事件激活

'----------- 如果安装了 OPC-DA Automation 2.1,使用:

Private Sub MyOPCGroup_DataChange(ByVal TransactionID As Long, ByVal NumItems As Long, ClientHandles() As Long, ItemValues() As Variant, Qualities() As Long, TimeStamps() As Date)

 '----------- 将数据表单元格的值设置为读取的数值

 Dim ii As Integer

 For ii = 1 To NumItems

fxItemValue(ClientHandles(ii)) = ItemValues(ii)

Next ii

  Range("A5").Value = CStr(TimeStamps(1))

  Range("B5").Value = CStr(fxItemValue(1))

 ' Range("C5").Value = Hex(Qualities(1))

  Range("C5").Value = CStr(fxItemValue(2))

  Range("D5").Value = CStr(fxItemValue(3))

  Range("E5").Value = CStr(fxItemValue(4))

  Range("F5").Value = CStr(fxItemValue(5))

  Range("G5").Value = CStr(fxItemValue(6))

End Sub

打印预览的代码

UserForm.Hide

Sheet1.PrintPreview

退出画面

UserForm.Hide

打开EXCEL激活宏。运行的界面如下,在服务器名称中输入相应的计算机节点名称,点击启动OPC客户端。就能得到相应的数据。

32.操作界面

至此完成了使用EXCEL通过OPC方式访问WinCC项目中数据的方法。