{{item.C_Name}}

问题

scl程序编译出错

精

奖

官

1582 产品版区：S7-300(F)/400(F)/400H(冗余)

文档类型：问题类别：产品选型问题类别：产品使用问题类别：故障诊断

刚刚接触scl，按照文档写了段程序，但编译出错，大家帮我看看
CONST
LIMIT :=7;
END_CONST

VAR_IN_OUT
sortbuffer :=ARRAY[0..LIMIT] OF INT;
END_VAR

VAR_OUTPUT
    calcbuffer:=ARRAY[0..LIMIT]OF
    STRUCT
         squareroot :INT;
         square: INT;
     END_STRUCT;
END_VAR

VAR_TEMP
    swap :BOOL;
    intex,aux :INT;
    valr,resurt:REAL;

END_VAR

BEGIN
REPEAT
    swap :=false;
    FOR index:=LIMIT TO 0 BY -1 DO
        IF sortbufer[index] < sortbuffer[index-1] THEN
            aux :=sortbuffer[index];
            sortbuffer[index]:=sortbuffer[index-1];
            sortbuffer[index-1] :=aux;
            swap :=1;
         END_IF;
    END_FOR;
    UNTIL NOT swap
END_REPEAT;

    FOR index:=0 TO limit BY 1 DO
        valr :=INT_TO_REAL sortbuffer[index];
        resurt:=SQRT (valr);
        calcbuffer.squareroot:=REAL_TO_INT (valr);
        calcbuffer.square:=SQUARE(sortbuffer[index]);

    END_FOR;

END_FUNCTION_BLOCK

问题补充：

扫码小程序：

一键登录查看全部问答

黄沐之资深学长

被采纳率 13.64%

问题为何被关闭

分享

手机扫码追踪该问题，
觉得实用，立即去分享！

点击复制链接
举报

去论坛讨论

参与「找答案」每周问答福利，提问或回答即可全民瓜分3000西币奖池，发1条也能分西币！用心解答更有机会单篇直发66西币，上不封顶。每周还有快答侠、夺魁答侠等专属称号与丰厚奖励等你来拿！西币可兑换实物奖品，随手互动免费领福利。

FUNCTION_BLOCK FB20 //EVALUATE
CONST
LIMIT1 := 7;
END_CONST
VAR_IN_OUT
sortbuffer : ARRAY[0..LIMIT1] OF INT;
END_VAR

VAR_OUTPUT
  calcbuffer : ARRAY[0..LIMIT1] OF
    STRUCT
      squareroot : INT;
      square : INT;
    END_STRUCT;
END_VAR

VAR_TEMP
  swap : BOOL;
  index, aux : INT;
  valr, resultr: REAL ;
END_VAR

BEGIN
REPEAT
  swap := FALSE;
    FOR index := LIMIT1 TO 1 BY -1 DO
      IF sortbuffer[index-1] > sortbuffer[index]
        THEN aux              :=sortbuffer[index];
        sortbuffer[index] := sortbuffer[index-1];
        sortbuffer[index-1] := aux;
        swap := TRUE;
      END_IF;
    END_FOR;
  UNTIL NOT swap
END_REPEAT;
FOR index := 0 TO LIMIT1 BY 1 DO
valr := INT_TO_REAL(sortbuffer[index]);
resultr := SQRT(valr);
calcbuffer[index].squareroot := REAL_TO_INT(resultr);
calcbuffer[index].square := SQUARE(sortbuffer[index]);
END_FOR;
END_FUNCTION_BLOCK
参考以上代码，SQUARE需要先行完成