小白学scl，求代写scl程序，有偿带带我。

FUNCTION_BLOCK "MAV"
TITLE = MAV
{ S7_Optimized_Access := 'TRUE' }
VERSION : 0.1
//电机关联阀门控制
   VAR_INPUT 
      KM : Bool;
      TimeA : Time := T#10s;
      TimeB : Time := T#10s;
   END_VAR

   VAR_OUTPUT 
      ValveA : Bool;
      ValveB : Bool;
   END_VAR

   VAR 
      LastKM { S7_SetPoint := 'True'} : Bool;
      Phase { S7_SetPoint := 'True'} : Int;
      TimerA {InstructionName := 'TON_TIME'; LibVersion := '1.0'} : TON_TIME;
      TimerB {InstructionName := 'TON_TIME'; LibVersion := '1.0'} : TON_TIME;
   END_VAR

BEGIN
 IF #KM = 0 THEN             //当KM = 0，转Phase=0(全关期间)
     #Phase := 0;
 ELSIF #LastKM = 0 THEN      //当KM0->1，转Phase=1(阀门A打开)
     #Phase := 1;
 END_IF;
 
 #LastKM := #KM;             //保存当前KM状态
 #ValveA := #Phase = 1;      //当#Phase=1，阀门A打开
 #ValveB := #Phase = 2;      //当#Phase=2，阀门B打开
 
 #TimerA(IN := #ValveA,      //控制阀门A开起的定时器
         PT := #TimeA);
 #TimerB(IN := #ValveB,      //控制阀门B开起的定时器
         PT := #TimeB);
 
 IF #TimerA.Q = 1 THEN       //阀门A工作时间到转#Phase=2
     #Phase := 2;
 END_IF;
 IF #TimerB.Q = 1 THEN       //阀门B工作时间到转#Phase=1
     #Phase := 1;
 END_IF;
END_FUNCTION_BLOCK