TIA WinCC如何实现自定义记录功能

巧了，正好有。我用的是access记录
1、要安装access，做好一个记录表。元素名称要和脚本中的一样，就好比你的过程值1，最好用英文（element2）。
2、在WinCC中插入脚本，在计划任务里触发一下脚本

Sub access_log()

' 启用错误提示
On Error Resume Next
' 创建变量
Dim db, rs, dbPath, tableName
Dim fieldName(4), fieldValue(4), elementsNumber, i
elementsNumber = 4
' 定义数据库路径
dbPath = "D:\test.accdb"
' 定义数据表名称
tableName = "log"
' 定义数据列的名称
fieldName(0) = "log_date"
fieldName(1) = "log_element1"
fieldName(2) = "log_element2"
fieldName(3) = "log_element3"
fieldName(4) = "log_element4"
' 定义数据列的值
fieldValue(0) = Now
fieldValue(1) = SmartTags("tag1")
fieldValue(2) = SmartTags("tag2")
fieldValue(3) = SmartTags("tag3")
fieldValue(4) = SmartTags("tag4")
' 创建控件
Set db = CreateObject("ADODB.Connection")
' 打开文件
db.Open "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & dbPath & ";"
' 判断打开状态
If db.State <> 1 Then
 ' 关闭数据库
 db.Close
 ' 释放资源
 Set db = Nothing
 ' 弹窗提示
 MsgBox "打开数据库失败" & vbCrLf & vbCrLf & "检查数据库是否存在" & vbCrLf & dbPath, vbCritical, "提示"
 ' 中止执行
 Exit Sub
End If
' 创建控件
Set rs = CreateObject("ADODB.Recordset")
' 打开数据表
rs.Open "SELECT * FROM " & tableName, db, 1, 3, 1
' 判断打开状态
If rs.State <> 1 Then
 ' 关闭数据表与数据库
 rs.Close
 db.Close
 ' 释放资源
 Set rs = Nothing
 Set db = Nothing
 ' 弹窗提示
 MsgBox "打开数据表失败" & vbCrLf & vbCrLf & "检查数据表是否存在" & vbCrLf & tableName, vbCritical, "提示"
 ' 中止执行
 Exit Sub
End If
' 添加新记录
rs.AddNew
' 写入变量
For i = 0 To elementsNumber
 rs.Fields(fieldName(i)).Value = fieldValue(i)
Next
' 更新数据表
rs.Update
' 关闭数据表与数据库
rs.Close
db.Close
' 释放资源
Set rs = Nothing
Set db = Nothing
' 弹窗提示
MsgBox "已成功记录", vbInformation, "提示"

End Sub