程序看不懂，不理解，高分送上

这是个斜坡程序，如果实际ramp小于设定ramp，则按扫描时间进行加减，直到二者相同为止      
       A     #EnableRamp  //是否使能
       JC    enab  //enableramp=1,则跳到enab

       L     #SetValue
       T     #OutputRamp //否则把setvalue送到outputramp
       BEU    //程序无条件结束
 enab: NOP   0 //空操作

 //Ramp End
       L     #SetValue
       L     #OutputRamp
       ==I    //二者想等吗?
       BEC     //如果setvalue=outputramp,则程序也结束,表示完成斜坡了

       L     #AuxRamp 
       RND   //把auxramp转换成双整数
       -I    //outputramp-auxramp=0?
       JZ    okva //如果=0则跳到okva
       L     #OutputRamp//不等于0,则取出outputramp
       ITD   //先整数转换成双整数
       DTR   //再转换成实数
       T     #AuxRamp  //然后送到auxramp
 okva: L     #SetValue 
       L     #OutputRamp
       >I    把setvalue和outputramp比较大小
       JC    incr                        //如果大于,则跳到incr,即执行斜坡+,否则往下执行斜坡-
       L     #TimeDown                   //取timedown(减速时间?)
       L     0
       ==I     //timedown和0比较
       L     #SetValue
       ITD   
       DTR   //把setvalue转换成实数
       JC    trdn //如果timedown=0,则跳到trdn
       L     "PLC_CYCLE_TIME" //取plc的扫描周期
       L     #EndScale
       ITD   
       DTR   //把endscale转换成实数
       *R    //plc_cycle_time和endscale相乘
       L     #TimeDown
       ITD   
       DTR   //把timedown转换成实数
       /R    //plc_cycle_time和endscale再除以timedown
       L     1.000000e-003               //取0.001,因为plc的扫描时间是ms,而计算用的是s
       *R    //plc_cycle_time和endscale相乘,再除以timedown再乘以0.001
       L     #AuxRamp                    //取ruxramp.
       TAK     //累加器1和累加器2交换
       -R    //即auxramp-((plc_cycle_time*endscale/timedown)*0.001)
 trdn: NOP   0 //空操作
       T     #AuxRamp //把结果送到auxramp
       RND   //转换成双整数
       L     #SetValue
       <=I   //auxramp和setvalue比较
       JC    trs  //如果auxramp<=setvalue则跳到trs(目的是比设定值小则outputramp=auxramp)

       TAK   如果大于的话,则累加器1和2交换(目的是比设定值大则outputramp=setvalue)
       JU    trs  //无条件跳到trs
 incr: NOP   0 //空操作,下面是斜坡-的程序,和斜坡+的程序类似,只不过一个是加一个是减而已
       L     #TimeUp                     //Tempo rampa in salita
       L     0
       ==I   
       L     #SetValue
       ITD   
       DTR   
       JC    trin
       L     "PLC_CYCLE_TIME"            //TEMPO CICLO PLC IN millesimi
       L     #EndScale
       ITD   
       DTR   
       *R    
       L     #TimeUp                     //Tempo rampa in salita
       ITD   
       DTR   
       /R    
       L     1.000000e-003               //TEMPO CICLO PLC IN millesimi
       *R    
       L     #AuxRamp
       +R    
 trin: T     #AuxRamp
       RND   
       L     #SetValue
       >=I   
       JC    trs
       TAK   
 trs:  T     #OutputRamp                 //把计算的结果送到outputramp