帮忙看一段STL的程序。

FB112的内容-------
  A     #DERR
      =     #ERR
      BEC   
      L     2
      T     #TOL
      L     #DPA
      SLD   3
      T     #PER_ADDR1
      L     4
NEXT: T     #ANZAHL
      L     PID [#PER_ADDR1]
      T     #READ1_BINARY
      NOP   0
      NOP   0
      NOP   0
      L     PID [#PER_ADDR1]
      T     #READ2_BINARY

      L     #READ1_BINARY
      L     #READ2_BINARY
      ==D   
      JC    EQUA
      L     #READ2_BINARY
      L     #TOL
      +D    
      L     #READ1_BINARY
      >=D   
      JCN   REP
      L     #READ2_BINARY
      L     #TOL
      -D    
      L     #READ1_BINARY
      <=D   
      JCN   REP
      JU    EQUA
REP:  L     #ANZAHL
      LOOP  NEXT
      S     #ERR
      NOP   0
      NOP   0

EQUA: R     #ERR
      A     #SET
      AN    #FLANC_SET
      =     #IMP_SET
      A     #SET
      =     #FLANC_SET
      AN    #IMP_SET
      JC    OUTP
      L     #READ2_BINARY
      AN    #INV
      JC    AA
      NEGD  
      SLD   8
      SRD   8
AA:   T     #YAA
      L     #SV
      T     #YAU
 
OUTP: L     #READ2_BINARY
      AN    #INV
      JC    BB
      NEGD  
      SLD   8
      SRD   8
BB:   T     #YPA
      L     #YAA                        //Absolute encoder set-pos stored with signal SET
      -D    
      T     #READ2_BIN_DIFF             //Diff. of abs.pos. - ABS_SET_POS
      L     #SF                         //Check RISE of 0 (not allowed RISE <=0)
      L     0.000000e+000
      <=R   
      JC    FA0
      L     #YAU
      L     4.096000e+003
      *R    
      L     #SF
      /R                                //SV calculated in absolute increments
      RND   
      L     #READ2_BIN_DIFF
      +D    
      JPZ   POVE                        //jump if result is positive (>=0)
      L     L#16777216                  //max.absolute encoder position (4096 rotationes) 
      +D    
POVE: T     #ABS_WITH_OFFSET
      L     #MO                         //Modulo (one complete scaled user cycle: e.g.360 degree)
      L     4096                        //Impulses per rotation
      *D    
      T     #ABS_MODULO
      L     #ABS_WITH_OFFSET
      L     #ABS_MODULO
      MOD                               //Rest of division= actual position area
      DTR   
      L     #SF
      *R    
      L     4.096000e+003
      /R    
      T     #YPU
      BEU   
FA0:  L     0.000000e+000
      T     #YPU
      BE