使用块传送SFC20时，如何才能用间接寻址呢？

FUNCTION FC 2 : INT
TITLE = 
//利用ANY指针进行数据复制。
//源数据区和目标数据区使用“数据块号”、“数据起始地址”、“传输字节数”来区分。
//FC2根据“数据块号”、“数据起始地址”、“传输字节数”来分配ANY指针。

VAR_INPUT
  QDB : INT ; //源数据块
  SSTA : INT ; //源起始地址
  NUMB : INT ; //传输字节数
  DDB : INT ; //目标数据块
  DSTA : INT ; //目标起始地址
END_VAR
VAR_TEMP
  SANY : ANY ; //源ANY指针
  DANY : ANY ; //目标ANY指针
END_VAR
BEGIN
NETWORK
TITLE = "分配源指针"

      L     W#16#1002; //类型：字节（修改ANY指针可以更改数据类型）
      T     LW     0; 
      L     #NUMB; //传输字节数目
      T     LW     2; 
      L     #QDB; //源数据块
      T     LW     4; 
      L     #SSTA; //源起始地址
      SLD   3; 
      OD    DW#16#84000000; 
      T     LD     6; 

NETWORK
TITLE = "分配目标指针"

      L     W#16#1002; //类型：字节
      T     LW    10; 
      L     #NUMB; //传输字节数目
      T     LW    12; 
      L     #DDB; //目标数据块
      T     LW    14; 
      L     #DSTA; //目标起始地址
      SLD   3; 
      OD    DW#16#84000000; 
      T     LD    16; 

NETWORK
TITLE = "复制数据"

      CALL "BLKMOV" (
           SRCBLK                   := #SANY,
           RET_VAL                  := #RET_VAL,
           DSTBLK                   := #DANY);

END_FUNCTION