找答案

300 STL看不懂 - 已解决问题

悬赏:10西币 | 解决时间：2021-12-14 21:39
产品版区： SIMATIC S7-300(F)/S7-400(F/H/FH) 2016LWW

很多300程序，都这样写是什么意思？希望大家用通俗的话指导一下，
感谢。。。。
     LAR1  P##t_SRC_Any
      L     W#16#1002
      T     LW [AR1,P#0.0]              //Fixed number 10H, 02H = Byte
      L     512
      T     LW [AR1,P#2.0]              //Data length = 512
      L     #t_SystemDB
      T     LW [AR1,P#4.0]              //DB number = system DB number
      L     0
      L     "M_IDB_PNIO".STAT11
      +I
      SLD   3
      T     LD [AR1,P#6.0]              //Start address = DBX(DB705.DBW1676 + 0).0
      L     B#16#84
      T     LB [AR1,P#6.0]              //84H = Data block

//Destination area pointer
      LAR1  P##t_DST_Any
      L     W#16#1002
      T     LW [AR1,P#0.0]              //Fixed number 10H, 02H = Byte
      L     512
      T     LW [AR1,P#2.0]              //Data length = 512
      L     #t_UserDB
      T     LW [AR1,P#4.0]              //DB number =user DB number
      L     0
      SLD   3
      T     LD [AR1,P#6.0]              //Start address = DBX0.0
      L     B#16#84
      T     LB [AR1,P#6.0]              //84H = Data block

//Move system data to user data block
      CALL  "BLKMOV"
       SRCBLK :=#t_SRC_Any
       RET_VAL:=#t_RET_VAL
       DSTBLK :=#t_DST_Any

问题补充：
LAR1 P##t_SRC_Any这句话啥意思，关键源跟目的也是临时变量ANY，怎么关联呀？谢谢

小程序:

扫码进入找答案小程序，即刻追踪此问题

还有问题，去提问

看了这个问题的网友还看了

最佳答案

1、想读懂这段程序，首先仔细看看下述有关 ANY数据的格式及ANY指针使用方法。
、ANY数据的格式，请见截图1与截图2。
、读懂这段程序的必备知识的相关资料
《S7-300/400PLC ANY指针使用详解》连接：
http://blog.sina.com.cn/s/blog_669692a601019hvt.html
2、解读第一段程序：
LAR1  P##t_SRC_Any  // P##t_SRC_Any(数据块首地址）存入指针AR1中。
      L     W#16#1002  //填写S7的固定数10H, 02H表示数据类型位字节。
      T     LW [AR1,P#0.0]  //见截图1中Byte0与截图2中Byte1。
      L     512
      T     LW [AR1,P#2.0]  //填写重复因子（数据长度）为512，见截图1中Byte2与Byte3。
      L     #t_SystemDB
      T     LW [AR1,P#4.0]  //填写DB的序号为系统DB 序号，见截图1中Byte4与Byte5。。
      L     0
      L     "M_IDB_PNIO".STAT11
      +I    // "M_IDB_PNIO".STAT11与偏移量（0）相加。
      SLD   3 // 相加结果左移3位（相当于结果乘以8）后形成地址指针的地址格式（见下述解释）。
      T     LD [AR1,P#6.0]   //将形成地址指针的地址作为数据区的首址，见截图1中Byte6与Byte7。。。
      L     B#16#84 //取十六进制常数84H
      T     LB [AR1,P#6.0]   //将84H存入截图1的Byte6中，84H表示为数据块（有关84H的用法见下述解释）。
2、有关解释：
、解释：相加结果左移3位（相当于结果乘以8）后形成地址指针的地址格式：
存储器间接寻址中的双字指针规定的格式为：　　
　　其0-2bit，指定bit位，3-18bit指定byte字节。其第31bit固定为0。　　
　　AR：　　
　　0000 0000 0000 0BBB BBBB BBBB BBBB BXXX 　　
　　这样规定，就意味着AR的取值只能是：0.0 ——65535.7 　　
　　例如：当AR=D4（hex）=0000 0000 0000 0000 0000 0000 1101 0100（b），实际上就是等于26.4。
、84H表示为数据块：
AR：　　
　　1000 0YYY 0000 0BBB BBBB BBBB BBBB BXXX 　　
　　比较一下两种格式的不同，我们发现，这里的第31bit被固定为1，同时，第24、25、26位有了可以取值的范围。聪明的你，肯定可以联想到，这是用于指定存储区域的。对，bit24-26的取值确定了要寻址的区域，它的取值是这样定义的：　
　　区域标识符　
　　26、25、24位　　
　　P（外部输入输出）：000 　　
　　I（输入映像区）：001 　　
　　Q（输出映像区）：010 　　　　
　　M（位存储区）：011 　　
　　DB（数据块）：100 　　
　　DI（背景数据块）：01 　　
　　L（暂存数据区，也叫局域数据）：111 　　
如果我们把这样的AR内容，用HEX表示的话，那么就有：　　
　　当是对DB区域寻址时，AR=840xxxxx 　

3、解读第二段程序：
与第一段意义相同，在此就不赘述了。
4、//Move system data to user data block
      CALL  "BLKMOV"
       SRCBLK :=#t_SRC_Any
       RET_VAL:=#t_RET_VAL
       DSTBLK :=#t_DST_Any
这是调用系统功能块SFC 20 。详见：
SFC20的功能，详见下述资料中的3.1 使用SFC20 “BLKMOV”复制存储区域：
、<S7-300400的系统软件和标准功能>下载：
http://www2.ad.siemens.com.cn/download/Upload/AS/manual/1023.pdf
、SFC20(BLKMOV)和ANY类型的用法：
http://blog.sina.com.cn/s/blog_669692a601019hvt.html

回答者：阿鸣回答时间：2021-12-11 12:41

提问者对于答案的评价：
谢谢

暂无评论

等您来回答

本版相关问题

其他答案

这些代码不是一两句可以解释清楚的。
结合 ANY 类型指针，指针的结构去理解。
//Destination area pointer   这行注释的上面部分是构造传送的源，ANY 类型的指针
//Destination area pointer 到  //Move system data to user data block 之间是构造目的地的 ANY 类型的指针
下面则是用了块传送指令。
S7-300和S7-400寻址  ID：79632832 2013年9月12日
https://support.industry.siemens.com/cs/document/79632832
西门子STL间接寻址常问问题集
https://support.industry.siemens.com/cs/document/76492353
SIMATIC S7-300和S7-400编程的语句表
https://support.industry.siemens.com/cs/document/109751814
间接寻址
http://www.ad.siemens.com.cn/productportal/Prods/published/Prog/Prog_2.4/Prog_2.4.html
利用ANY指针参数化SFC 20 (BLKMOV)
https://support.industry.siemens.com/cs/document/2738030

回答者：大宝朱林森 2021-12-10 22:21

这里开始是形成源地址指针的
LAR1  P##t_SRC_Any
      L     W#16#1002
      T     LW [AR1,P#0.0]              //Fixed number 10H, 02H = Byte
      L     512
      T     LW [AR1,P#2.0]              //Data length = 512
      L     #t_SystemDB
      T     LW [AR1,P#4.0]              //DB number = system DB number
      L     0
      L     "M_IDB_PNIO".STAT11
      +I
      SLD   3
      T     LD [AR1,P#6.0]              //Start address = DBX(DB705.DBW1676 + 0).0
      L     B#16#84
      T     LB [AR1,P#6.0]              //84H = Data block
上面是源地址指针的形成
下面开始是目标地址指针
//Destination area pointer
      LAR1  P##t_DST_Any
      L     W#16#1002
      T     LW [AR1,P#0.0]              //Fixed number 10H, 02H = Byte
      L     512
      T     LW [AR1,P#2.0]              //Data length = 512
      L     #t_UserDB
      T     LW [AR1,P#4.0]              //DB number =user DB number
      L     0
      SLD   3
      T     LD [AR1,P#6.0]              //Start address = DBX0.0
      L     B#16#84
      T     LB [AR1,P#6.0]              //84H = Data block
到这里上面是目标地址指针
下面就是调用BLKMOV 从原地址复制到目标地址，类似从P#DB1.DBX0.0 BYTE 50复制到P#DB2.DBX0.0 BYTE 50，这样，具体的地址要根据里面的临时变量确定
//Move system data to user data block
      CALL  "BLKMOV"
       SRCBLK :=#t_SRC_Any
       RET_VAL:=#t_RET_VAL
       DSTBLK :=#t_DST_Any

关于指针的含义可以参考手册：
SIMATIC 用STEP 7 V5.5 编程手册
https://support.industry.siemens.com/cs/cn/zh/view/45531107
604页 27.3.4.2 参数类型 POINTER 的格式
610页 27.3.4.5 参数类型 ANY 的格式

本回答有1位钻石用户推荐

回答者： RENHQ 2021-12-10 22:27

你需要学习一下STL的编程知识，多看看STL编程手册，指令含义

回答者：轻风流云 2021-12-11 14:48

是的，先看看STL编程手册，了解一下程序用到的指令含义，再有什么问题可以请教教论坛里大神们，这样也学的扎实不是，，，

回答者： 2020911 2021-12-12 11:24

来自找答案小程序

没有解决我的问题，去提问！

找答案

自动化系统

驱动技术

数控系统

低压电器产品

过程仪表、分析仪器及称...

300 STL看不懂 - 已解决问题

20秒帮我们优化支持中心！

找答案

自动化系统

驱动技术

数控系统

低压电器产品

过程仪表、分析仪器及称...

300 STL看不懂 - 已解决问题

20秒帮我们优化支持中心！

系统提示

系统提示

系统提示

验证码登录 密码登录

验证码登录

密码登录