UNCTION_BLOCK "DispFB"
TITLE =
AUTHOR : Zane
FAMILY :
NAME :
VERSION : 1.0


VAR_INPUT
LADDR : WORD := W#16#100; //模拟量起始地址
END_VAR
VAR
Channel_Cnt : INT ; //模拟通道计数器
Channel_Total : INT := 48; //所有模拟量通道
Channel_Conv_Ratio : REAL := 1.000000e+001; //模拟量值转换系数
Channel_Err_Code : WORD := W#16#7FFF; //模拟量通道出错值
Channel_Chk_Byte : "Sensor_Err_Bit_Table"; //模拟量通道故障标志位
Channel_Value : "Analog_Table"; //模拟量通道转换值
END_VAR
VAR_TEMP
Channel_Buf : WORD ; //临时变量
Channel_Value_Buf : REAL ; //临时变量
Channel_Signal_Buf : BOOL ; //临时变量
END_VAR
BEGIN
NETWORK
TITLE =

L 0;
T #Channel_Cnt;

lp01: L #LADDR;
SLW 3;
LAR1 ;
L #Channel_Cnt;
L 2;
*I ;
SLW 3;
+AR1 ;
L PIW [AR1,P#0.0];
T #Channel_Buf;
L #Channel_Err_Code;
==I ;
= #Channel_Signal_Buf;

L #Channel_Buf;
ITD ;
DTR ;
L #Channel_Conv_Ratio;
/R ;
T #Channel_Value_Buf;

LAR1 P##Channel_Chk_Byte;
L #Channel_Cnt;
+AR1 ;
O #Channel_Signal_Buf;
O ;
A DIX [AR1,P#0.0];
AN "RST_SB";
= DIX [AR1,P#0.0];

LAR1 P##Channel_Value;
L #Channel_Cnt;
L 4;
*I ;
SLW 3;
+AR1 ;
L #Channel_Value_Buf;
T DID [AR1,P#0.0];

L #Channel_Cnt;
L 1;
+I ;
T #Channel_Cnt;
L #Channel_Total;
>=I ;
JCN lp01;
BE ;

END_FUNCTION_BLOCK